;Skrypt bY SabiK
;jedzenie.txt
;Wersja 2.4
;Gdy postac zglodnieje (pojawi sie w grze komunikat "Czujesz sie dobrze")
;lub po nacisnieciu klawisza '%key1 %key2'
;Skrypt skanuje poziom glodu, bialka, witamin i weglowodanow i zaspokaja go do poziomu optymalnego
;Gdy nie masz jedzenia skrypt odtwarza dzwiek
;!!!UWAGA!!!
;Musisz miec w pojemniku, na widoku chleb, salatke, ciasteczka, ser i sok kokosowy
;W tym czasie musi byc aktywne okno ultimy
;Najlepiej miec wylaczone inne skrypty wykonujace czynnosci dlugoterminowe (przeszkadzajace w jedzeniu, np. magia, krawiec, alchemia itd.)
;lub ustawic w nich petle, ktora zatrzymuje skrypt gdy "*STOP = 1"

;U W A G A !!! USTAW PONIZSZE ZMIENNE PRZED WLACZENIEM SKRYPTU !!!
set %sciezka E:\xxx.wav         ;Tutaj ustaw sciezke do dzwieku
set %jedzenie 1                       ;Tutaj ustaw czy skrypt ma jesc [1]-Po pokazaniu sie komunikatu 'Czujesz sie dobrze' czy [2]-Po wcisnieciu klawisza '%key'
set %key1 x                           ;Tutaj ustaw klawisz pod ktorym skrypt bedzie jadl
set %key2 ctrl                        ;Tutaj ustaw drugi klawisz [ctrl,alt,shift lub zostaw puste]
;------------------------------------------------------------------------------

set *STOP 0
set #sysmsgcol 63
event sysmessage Skrypt [jedzenie] odpalony (bY SabiK)
wait 1

start1:
if %jedzenie = 2
{
   onhotkey %key1 %key2
      goto start
}
else
{
   for %journal 1 3
   {
      scanjournal %journal
      if Czujesz_sie_dobrze in #journal || Moglbys_czuc_sie_lepiej in #journal || Czujesz_sie_ospaly_i_zmeczony in #journal
      {
         if *STOP = 1
         {
            repeat
            until *STOP = 0
         }
         goto start
      }
   }
   if %sprawdz = 1
   {
      if %sprawdz_time < #scnt2
      {
         if *STOP = 1
         {
            repeat
            until *STOP = 0
         }
         set %sprawdz 0
         goto start
      }
   }
}
goto start1

start:
set *STOP 1
set %jedz 0
if %jedzenie <> 2
   wait 70
if #contname notin text_gump , #spc , container_gump , #spc , paperdoll_gump , #spc , status_gump , #spc , radar_gump || ( #contname = generic_gump && #contsize notin 400_220 , #spc , 400_320 , #spc , 400_420 , #spc , 400_520 , #spc , 400_380 )
{
   set %x #contposx + 30
   set %y #contposy + 30
   click %x %y r
   wait 20
}
skills:
event macro 8 4
set %licz #scnt2 + 35
repeat
if #contname = generic_gump && #contsize = 400_380 && #contposx = 0 && #contposy = 0
   goto jedzenie
if %licz < #scnt2
   goto skills
until #contname = generic_gump && #contposx = 0 && #contposy = 0 && #contsize in 400_220 , #spc , 400_320 , #spc , 400_420 , #spc , 400_520
info:
click 259 41
wait 10
set %licz #scnt2 + 35
repeat
if #contname = generic_gump && #contposx = 0 && #contposy = 0 && #contsize in 400_220 , #spc , 400_320 , #spc , 400_420 , #spc , 400_520
   goto info
if %licz < #scnt2
   goto start
until #contname = generic_gump && #contsize = 400_380 && #contposx = 0 && #contposy = 0

jedzenie:
if #targcurs = 1
   key esc
set %glod 0
set %bialka 0
set %witaminy 0
set %weglowodany 0
if %jedz = 1
{
   jedz:
   set %jedz 0
   click 38 41
   wait 5
   set %licz #scnt2 + 35
   repeat
   if %licz < #scnt2
      goto start
   until #contname = generic_gump && #contsize = 400_380 && #contposx = 0 && #contposy = 0
}
savepix 265 253 1
gosub sprawdz_czy_glodny glod 254
savepix 265 273 1
gosub sprawdz_czy_glodny bialka 274
savepix 265 293 1
gosub sprawdz_czy_glodny witaminy 294
savepix 265 313 1
gosub sprawdz_czy_glodny weglowodany 314

if %glod = 0 && %bialka = 0 && %witaminy = 0 && %weglowodany = 0
{
   gosub zjedz MGG chleba
   if #result = koniec
      goto koniec
   if %jedz = 1
      goto jedzenie
   gosub zjedz JGI salatki
   if #result = koniec
      goto koniec
   if %jedz = 1
      goto jedzenie
   gosub zjedz SLI ciasteczek
   if #result = koniec
      goto koniec
   set %jedz 1
   goto jedzenie
}
if %glod = 1 && %bialka = 0 && %witaminy = 0 && %weglowodany = 0
{
   gosub zjedz ZBM soku , #spc , kokosowego
   if #result = koniec
      goto koniec
   set %jedz 1
   goto jedzenie
}
if %bialka = 0
{
   if %glod = 1
   {
      gosub zjedz END sera
      if #result = koniec
         goto koniec
      set %jedz 1
      goto jedzenie
   }
   else
   {
      gosub zjedz MGG chleba
      if #result = koniec
         goto koniec
      set %jedz 1
      goto jedzenie
   }
}
if %witaminy = 0
{
   gosub zjedz JGI salatki
   if #result = koniec
      goto koniec
   set %jedz 1
   goto jedzenie
}
if %weglowodany = 0
{
   gosub zjedz SLI ciasteczek
   if #result = koniec
      goto koniec
   set %jedz 1
   goto jedzenie
}
if %glod = 0 && %bialka = 1 && %witaminy = 1 && %weglowodany = 1
{
   gosub zjedz MGG chleba
   if #result = koniec
      goto koniec
   set %jedz 1
   goto jedzenie
}
koniec:
click 311 260 r
set #sysmsgcol 88
event sysmessage Zakonczono jedzenie!
set *STOP 0
goto start1


;/// --- Subs ---

sub sprawdz_czy_glodny
gosub sprawdz_czy_najedzony
else
{   ;przejedzenie
   savepix 203 %2 1
   gosub sprawdz_czy_najedzony
   savepix 258 %2 1
   gosub sprawdz_czy_najedzony
}
return

sub sprawdz_czy_najedzony
gosub sprawdz_czy_na_wierzchu
if #pixcol = 11392710 || #pixcol = 11392966
   set % . %1 1
return

sub sprawdz_czy_na_wierzchu
if #pixcol = 4294967295
{
   display ok UO na wierzch!
   wait 30
}
return

sub zjedz
finditem %1 C
if #findkind = -1
{
   set #sysmsgcol 1080
   if %jedzenie <> 2
   {
      event sysmessage Nie znalazlem %2 , ! Sprawdze za 30 sekund
      set %sprawdz 1
      set %sprawdz_time #scnt2 + 300
   }
   else
   event sysmessage Nie znalazlem %2 , ! Anulowano jedzenie
   sound %sciezka
   return koniec
}
set #lobjectid #findid
event macro 17
wait 22
for %journal 1 2
{
   scanjournal %journal
   if #journal = Czujesz_sie_w_pelni_sil. || #journal = Czujesz_sie_ciezki_i_zmeczony. || #journal = Czujesz_sie_ciezka_i_zmeczona. || masz_ochote_zwymiotowac in #journal
   {
      set %jedz 1
      return
   }
}
return